[PATCH] gnu: Add pbuilder.

DoneSubmitted by Efraim Flashner.
Details
2 participants
  • Efraim Flashner
  • Maxime Devos
Owner
unassigned
Severity
normal
E
E
Efraim Flashner wrote on 24 May 09:59 +0200
(address . guix-patches@gnu.org)
f5e751aede80501bb9bee5edf99e669c9b719d77.1653378760.git.efraim@flashner.co.il
* gnu/packages/debian.scm (pbuilder): New variable.
---
gnu/packages/debian.scm | 145 ++++++++++++++++++++++++++++++++++++++++
1 file changed, 145 insertions(+)

With this I was able to use `sudo -E pbuilder create` to create a new base
chroot for building packages and I was able to download the source
packages for hello to run `sudo -E pbuilder build ~/hello_2.10-2.dsc` to
actually build a hello binary.

For reproducing:
(on Guix System, in ~/.pbuilderrc, as a minimum:
PBUILDERROOTCMD="/run/setuid-programs/sudo -E")


guix shell pbuilder -- sudo -E pbuilder create
guix shell pbuilder -- sudo -E pbuilder build /path/to/hello_2.10-2.dsc

---

Toggle diff (167 lines)
diff --git a/gnu/packages/debian.scm b/gnu/packages/debian.scm
index 2efd8114be..737ff9b892 100644
--- a/gnu/packages/debian.scm
+++ b/gnu/packages/debian.scm
@@ -36,6 +36,8 @@ (define-module (gnu packages debian)
   #:use-module (gnu packages gettext)
   #:use-module (gnu packages gnupg)
   #:use-module (gnu packages guile)
+  #:use-module (gnu packages linux)
+  #:use-module (gnu packages man)
   #:use-module (gnu packages ncurses)
   #:use-module (gnu packages perl)
   #:use-module (gnu packages pkg-config)
@@ -417,6 +419,149 @@ (define-public dpkg
 handling the installation and removal of Debian software packages.")
     (license license:gpl2+)))
 
+(define-public pbuilder
+  (package
+    (name "pbuilder")
+    (version "0.231")
+    (source
+      (origin
+        (method git-fetch)
+        (uri (git-reference
+               (url "https://salsa.debian.org/pbuilder-team/pbuilder.git/")
+               (commit version)))
+        (file-name (git-file-name name version))
+        (sha256
+         (base32 "0z6f1fgcrkfql9ayc3d0nxra2y6cn91xd5lvr0hd8gdlp9xdvxbc"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list
+       #:phases
+       #~(modify-phases %standard-phases
+           (delete 'configure)          ; no configure script
+           (add-after 'unpack 'patch-source
+             (lambda* (#:key native-inputs inputs outputs #:allow-other-keys)
+
+               ;; Documentation requires tldp-one-page.xsl
+               (substitute* "Makefile"
+                 ((".*-C Documentation.*") ""))
+
+               ;; Don't create #$output/var/cache/pbuilder/...
+               (substitute* '("Makefile"
+                              "pbuildd/Makefile")
+                 ((".*/var/cache/pbuilder.*") ""))
+
+               ;; Find the correct fallback location.
+               (substitute* '("pbuilder-checkparams"
+                              "pbuilder-loadconfig"
+                              "pbuilder-satisfydepends-apt"
+                              "pbuilder-satisfydepends-aptitude"
+                              "pbuilder-satisfydepends-classic"
+                              "t/test_pbuilder-satisfydepends-classic")
+                 (("\\$PBUILDER_ROOT(/usr)?") #$output))
+
+               ;; Some hardcoded paths
+               (substitute* '("debuild-pbuilder"
+                              "pbuilder"
+                              "pbuilder-buildpackage"
+                              "pbuilderrc"
+                              "pdebuild"
+                              "pdebuild-checkparams"
+                              "pdebuild-internal")
+                 (("/usr/lib/pbuilder")
+                  (string-append #$output "/lib/pbuilder")))
+               (substitute* "pbuildd/buildd-config.sh"
+                 (("/usr/share/doc/pbuilder")
+                  (string-append #$output "/share/doc/pbuilder")))
+               (substitute* "pbuilder-unshare-wrapper"
+                 (("/(s)?bin/ifconfig") "ifconfig")
+                 (("/(s)?bin/ip")
+                  (search-input-file (or native-inputs inputs) "/sbin/ip")))
+               (substitute* "Documentation/Makefile"
+                 (("/usr") ""))
+
+               ;; Ensure PATH works both in Guix and within the Debian chroot.
+               (substitute* "pbuilderrc"
+                 (("PATH=\"/usr/sbin:/usr/bin:/sbin:/bin")
+                  "PATH=\"$PATH:/usr/sbin:/usr/bin:/sbin:/bin"))))
+           (add-after 'install 'create-etc-pbuilderrc
+             (lambda* (#:key outputs #:allow-other-keys)
+               (with-output-to-file (string-append #$output "/etc/pbuilderrc")
+                 (lambda ()
+                   (format #t "# A couple of presets to make this work more smoothly.~@
+                           MIRRORSITE=\"http://deb.debian.org/debian\"~@
+                           PBUILDERSATISFYDEPENDSCMD=\"~a/lib/pbuilder/pbuilder-satisfydepends-apt\"~%"
+                           #$output)))))
+           (add-after 'install 'install-manpages
+             (lambda* (#:key outputs #:allow-other-keys)
+               (let ((man (string-append #$output "/share/man/")))
+                 (install-file "debuild-pbuilder.1" (string-append man "man1"))
+                 (install-file "pdebuild.1" (string-append man "man1"))
+                 (install-file "pbuilder.8" (string-append man "man8"))
+                 (install-file "pbuilderrc.5" (string-append man "man5")))))
+           (add-after 'install-more 'wrap-programs
+             (lambda* (#:key native-inputs inputs outputs #:allow-other-keys)
+               (for-each
+                 (lambda (file)
+                   (wrap-script file
+                    `("PATH" ":" prefix
+                      (,(dirname (search-input-file (or native-inputs inputs) "/bin/cut"))
+                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/dpkg"))
+                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/grep"))
+                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/perl"))
+                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/sed"))
+                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/which"))
+                       ,(dirname (search-input-file (or native-inputs inputs) "/sbin/debootstrap"))))))
+                 (cons*
+                   (string-append #$output "/bin/pdebuild")
+                   (string-append #$output "/sbin/pbuilder")
+                   (find-files (string-append #$output "/lib/pbuilder"))))))
+           ;; Move the 'check phase to after 'install.
+           (delete 'check)
+           (add-after 'wrap-programs 'check
+             (assoc-ref %standard-phases 'check)))
+         #:make-flags
+         ;; No PREFIX, use DESTDIR instead.
+         #~(list (string-append "DESTDIR=" #$output)
+                 (string-append "SYSCONFDIR=" #$output "/etc")
+                 (string-append "BINDIR=" #$output "/bin")
+                 (string-append "PKGLIBDIR=" #$output "/lib/pbuilder")
+                 (string-append "SBINDIR=" #$output "/sbin")
+                 (string-append "PKGDATADIR=" #$output "/share/pbuilder")
+                 (string-append "EXAMPLEDIR=" #$output "/share/doc/pbuilder/examples")
+                 "PBUILDDDIR=/share/doc/pbuilder/examples/pbuildd/")))
+    (inputs
+     (list dpkg
+           debootstrap
+           grep
+           guile-3.0            ; for wrap-script
+           iproute
+           perl
+           which))
+    (native-inputs
+     (list man-db
+           util-linux))
+    (home-page "https://pbuilder-team.pages.debian.net/pbuilder/")
+    (synopsis "Personal package builder for Debian packages")
+    (description
+     "@code{pbuilder} is a personal package builder for Debian packages.
+@itemize
+@item@code{pbuilder} constructs a chroot system, and builds a package inside the
+chroot.  It is an ideal system to use to check that a package has correct
+build-dependencies.  It uses @code{apt} extensively, and a local mirror, or a
+fast connection to a Debian mirror is ideal, but not necessary.
+@item@code{pbuilder create} uses debootstrap to create a chroot image.
+@item@code{pbuilder update} updates the image to the current state of
+testing/unstable/whatever.
+@item@code{pbuilder build} takes a @code{*.dsc} file and builds a binary in the
+chroot image.
+@item@code{pdebuild} is a wrapper for Debian Developers, to allow running
+@code{pbuilder} just like @code{debuild}, as a normal user.
+@end itemize
+NOTE: For Guix System it is recommended to put
+@code{PBUILDERROOTCMD=\"/run/setuid-programs/sudo -E\"} inside of your
+@file{~/.pbuilderrc}.")
+    (license license:gpl2+)))
+
 (define-public reprepro
   (package
     (name "reprepro")

base-commit: 1a1f9e7050a9b787b2111cb5af677510a0122e2b
-- 
2.36.1
M
M
Maxime Devos wrote on 24 May 12:09 +0200
(name . Vagrant Cascadian)(address . vagrant@debian.org)
5f757b843a3ecc0c601adc87fcc5208ba3a415b5.camel@telenet.be
Efraim Flashner schreef op di 24-05-2022 om 10:59 [+0300]:
Toggle quote (14 lines)
> +           (add-after 'install-more 'wrap-programs
> +             (lambda* (#:key native-inputs inputs outputs #:allow-other-keys)
> +               (for-each
> +                 (lambda (file)
> +                   (wrap-script file
> +                    `("PATH" ":" prefix
> +                      (,(dirname (search-input-file (or native-inputs inputs) "/bin/cut"))
> +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/dpkg"))
> +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/grep"))
> +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/perl"))
> +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/sed"))
> +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/which"))
> +                       ,(dirname (search-input-file (or native-inputs inputs) "/sbin/debootstrap"))))))

Shouldn't these be inputs instead of native-inputs, because they will
end up being run when pbuilder is run? Likewise for'patch-source'.
Also, can be simplified to

[...] "PATH" ":" prefix ,(map (compose dirname (cut search-input-file inputs <>)) '("/bin/cut" "/bin/dpkg" ...)) [...]
-----BEGIN PGP SIGNATURE-----

iI0EABYKADUWIQTB8z7iDFKP233XAR9J4+4iGRcl7gUCYoyu4BccbWF4aW1lZGV2
b3NAdGVsZW5ldC5iZQAKCRBJ4+4iGRcl7r5aAP9QhYZ2FjOydZw4CzxawQf7pRA9
IyKbKR5AmsMFX80ARwEAuuKSoBVjf/JtRZbkX0rRGClOjTwGNXn+9jG3no3e4Qg=
=fsDw
-----END PGP SIGNATURE-----


E
E
Efraim Flashner wrote on 25 May 10:41 +0200
Re: [bug#55608] [PATCH v2] gnu: Add pbuilder.
(name . Maxime Devos)(address . maximedevos@telenet.be)
Yo3r0B5elnKfwD++@3900XT
On Tue, May 24, 2022 at 12:09:36PM +0200, Maxime Devos wrote:
Toggle quote (18 lines)
> Efraim Flashner schreef op di 24-05-2022 om 10:59 [+0300]:
> > +           (add-after 'install-more 'wrap-programs
> > +             (lambda* (#:key native-inputs inputs outputs #:allow-other-keys)
> > +               (for-each
> > +                 (lambda (file)
> > +                   (wrap-script file
> > +                    `("PATH" ":" prefix
> > +                      (,(dirname (search-input-file (or native-inputs inputs) "/bin/cut"))
> > +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/dpkg"))
> > +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/grep"))
> > +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/perl"))
> > +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/sed"))
> > +                       ,(dirname (search-input-file (or native-inputs inputs) "/bin/which"))
> > +                       ,(dirname (search-input-file (or native-inputs inputs) "/sbin/debootstrap"))))))
>
> Shouldn't these be inputs instead of native-inputs, because they will
> end up being run when pbuilder is run? Likewise for'patch-source'.

I figured using (or native-inputs inputs) would help with
cross-building, but I've changed it to just inputs. Also in the other
spot where I used that. I tried cross building it before but got stuck
in one of the dependencies.

Toggle quote (4 lines)
> Also, can be simplified to
>
> [...] "PATH" ":" prefix ,(map (compose dirname (cut search-input-file inputs <>)) '("/bin/cut" "/bin/dpkg" ...)) [...]

Thanks, I knew there was some way to make it much cleaner.

I've made the changes you've suggested and also adjusted
#$output/etc/pbuilderrc to use /run/setuid-programs/sudo if it's
available and removed the note from the bottom of the package
description since it's no longer necessary.



--
Efraim Flashner <efraim@flashner.co.il> אפרים פלשנר
GPG key = A28B F40C 3E55 1372 662D 14F7 41AA E7DC CA3D 8351
Confidentiality cannot be guaranteed on emails sent or received unencrypted
From 2daaaacb03652c53891bc95306e6d5cc8a07ab90 Mon Sep 17 00:00:00 2001
Message-Id: <2daaaacb03652c53891bc95306e6d5cc8a07ab90.1653467875.git.efraim@flashner.co.il>
From: Efraim Flashner <efraim@flashner.co.il>
Date: Tue, 24 May 2022 10:52:20 +0300
Subject: [PATCH v2] gnu: Add pbuilder.

* gnu/packages/debian.scm (pbuilder): New variable.
---
gnu/packages/debian.scm | 151 +++++++++++++++++++++++++++++++++++++++-
1 file changed, 150 insertions(+), 1 deletion(-)

Toggle diff (176 lines)
diff --git a/gnu/packages/debian.scm b/gnu/packages/debian.scm
index 2efd8114be..05440d9444 100644
--- a/gnu/packages/debian.scm
+++ b/gnu/packages/debian.scm
@@ -36,10 +36,13 @@ (define-module (gnu packages debian)
   #:use-module (gnu packages gettext)
   #:use-module (gnu packages gnupg)
   #:use-module (gnu packages guile)
+  #:use-module (gnu packages linux)
+  #:use-module (gnu packages man)
   #:use-module (gnu packages ncurses)
   #:use-module (gnu packages perl)
   #:use-module (gnu packages pkg-config)
-  #:use-module (gnu packages wget))
+  #:use-module (gnu packages wget)
+  #:use-module (srfi srfi-26))
 
 (define-public debian-archive-keyring
   (package
@@ -417,6 +420,152 @@ (define-public dpkg
 handling the installation and removal of Debian software packages.")
     (license license:gpl2+)))
 
+(define-public pbuilder
+  (package
+    (name "pbuilder")
+    (version "0.231")
+    (source
+      (origin
+        (method git-fetch)
+        (uri (git-reference
+               (url "https://salsa.debian.org/pbuilder-team/pbuilder.git/")
+               (commit version)))
+        (file-name (git-file-name name version))
+        (sha256
+         (base32 "0z6f1fgcrkfql9ayc3d0nxra2y6cn91xd5lvr0hd8gdlp9xdvxbc"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list
+       #:modules `((guix build gnu-build-system)
+                   (guix build utils)
+                   (srfi srfi-26))
+       #:phases
+       #~(modify-phases %standard-phases
+           (delete 'configure)          ; no configure script
+           (add-after 'unpack 'patch-source
+             (lambda* (#:key inputs outputs #:allow-other-keys)
+
+               ;; Documentation requires tldp-one-page.xsl
+               (substitute* "Makefile"
+                 ((".*-C Documentation.*") ""))
+
+               ;; Don't create #$output/var/cache/pbuilder/...
+               (substitute* '("Makefile"
+                              "pbuildd/Makefile")
+                 ((".*/var/cache/pbuilder.*") ""))
+
+               ;; Find the correct fallback location.
+               (substitute* '("pbuilder-checkparams"
+                              "pbuilder-loadconfig"
+                              "pbuilder-satisfydepends-apt"
+                              "pbuilder-satisfydepends-aptitude"
+                              "pbuilder-satisfydepends-classic"
+                              "t/test_pbuilder-satisfydepends-classic")
+                 (("\\$PBUILDER_ROOT(/usr)?") #$output))
+
+               ;; Some hardcoded paths
+               (substitute* '("debuild-pbuilder"
+                              "pbuilder"
+                              "pbuilder-buildpackage"
+                              "pbuilderrc"
+                              "pdebuild"
+                              "pdebuild-checkparams"
+                              "pdebuild-internal")
+                 (("/usr/lib/pbuilder")
+                  (string-append #$output "/lib/pbuilder")))
+               (substitute* "pbuildd/buildd-config.sh"
+                 (("/usr/share/doc/pbuilder")
+                  (string-append #$output "/share/doc/pbuilder")))
+               (substitute* "pbuilder-unshare-wrapper"
+                 (("/(s)?bin/ifconfig") "ifconfig")
+                 (("/(s)?bin/ip") (search-input-file inputs "/sbin/ip")))
+               (substitute* "Documentation/Makefile"
+                 (("/usr") ""))
+
+               ;; Ensure PATH works both in Guix and within the Debian chroot.
+               (substitute* "pbuilderrc"
+                 (("PATH=\"/usr/sbin:/usr/bin:/sbin:/bin")
+                  "PATH=\"$PATH:/usr/sbin:/usr/bin:/sbin:/bin"))))
+           (add-after 'install 'create-etc-pbuilderrc
+             (lambda* (#:key outputs #:allow-other-keys)
+               (with-output-to-file (string-append #$output "/etc/pbuilderrc")
+                 (lambda ()
+                   (format #t "# A couple of presets to make this work more smoothly.~@
+                           MIRRORSITE=\"http://deb.debian.org/debian\"~@
+                           if [ -r /run/setuid-programs/sudo ]; then~@
+                               PBUILDERROOTCMD=\"/run/setuid-programs/sudo -E\"~@
+                           fi~@
+                           PBUILDERSATISFYDEPENDSCMD=\"~a/lib/pbuilder/pbuilder-satisfydepends-apt\"~%"
+                           #$output)))))
+           (add-after 'install 'install-manpages
+             (lambda* (#:key outputs #:allow-other-keys)
+               (let ((man (string-append #$output "/share/man/")))
+                 (install-file "debuild-pbuilder.1" (string-append man "man1"))
+                 (install-file "pdebuild.1" (string-append man "man1"))
+                 (install-file "pbuilder.8" (string-append man "man8"))
+                 (install-file "pbuilderrc.5" (string-append man "man5")))))
+           (add-after 'install 'wrap-programs
+             (lambda* (#:key inputs outputs #:allow-other-keys)
+               (for-each
+                 (lambda (file)
+                   (wrap-script file
+                    `("PATH" ":" prefix
+                      ,(map (compose dirname (cut search-input-file inputs <>))
+                            (list "/bin/cut"
+                                  "/bin/dpkg"
+                                  "/bin/grep"
+                                  "/bin/perl"
+                                  "/bin/sed"
+                                  "/bin/which"
+                                  "/sbin/debootstrap")))))
+                 (cons*
+                   (string-append #$output "/bin/pdebuild")
+                   (string-append #$output "/sbin/pbuilder")
+                   (find-files (string-append #$output "/lib/pbuilder"))))))
+           ;; Move the 'check phase to after 'install.
+           (delete 'check)
+           (add-after 'validate-runpath 'check
+             (assoc-ref %standard-phases 'check)))
+         #:make-flags
+         ;; No PREFIX, use DESTDIR instead.
+         #~(list (string-append "DESTDIR=" #$output)
+                 (string-append "SYSCONFDIR=" #$output "/etc")
+                 (string-append "BINDIR=" #$output "/bin")
+                 (string-append "PKGLIBDIR=" #$output "/lib/pbuilder")
+                 (string-append "SBINDIR=" #$output "/sbin")
+                 (string-append "PKGDATADIR=" #$output "/share/pbuilder")
+                 (string-append "EXAMPLEDIR=" #$output "/share/doc/pbuilder/examples")
+                 "PBUILDDDIR=/share/doc/pbuilder/examples/pbuildd/")))
+    (inputs
+     (list dpkg
+           debootstrap
+           grep
+           guile-3.0            ; for wrap-script
+           iproute
+           perl
+           which))
+    (native-inputs
+     (list man-db
+           util-linux))
+    (home-page "https://pbuilder-team.pages.debian.net/pbuilder/")
+    (synopsis "Personal package builder for Debian packages")
+    (description
+     "@code{pbuilder} is a personal package builder for Debian packages.
+@itemize
+@item@code{pbuilder} constructs a chroot system, and builds a package inside the
+chroot.  It is an ideal system to use to check that a package has correct
+build-dependencies.  It uses @code{apt} extensively, and a local mirror, or a
+fast connection to a Debian mirror is ideal, but not necessary.
+@item@code{pbuilder create} uses debootstrap to create a chroot image.
+@item@code{pbuilder update} updates the image to the current state of
+testing/unstable/whatever.
+@item@code{pbuilder build} takes a @code{*.dsc} file and builds a binary in the
+chroot image.
+@item@code{pdebuild} is a wrapper for Debian Developers, to allow running
+@code{pbuilder} just like @code{debuild}, as a normal user.
+@end itemize")
+    (license license:gpl2+)))
+
 (define-public reprepro
   (package
     (name "reprepro")

base-commit: d129d962e437fd215c5e9428fc1b26e2d72ffbda
-- 
2.36.1
-----BEGIN PGP SIGNATURE-----

iQIzBAABCgAdFiEEoov0DD5VE3JmLRT3Qarn3Mo9g1EFAmKN688ACgkQQarn3Mo9
g1GFPg/9EBS3nvgM96ZC+WgOFlgnEORTXI2nkcpIE9ckHqcF4RS0dnvev9iQuR1u
nRe7Y5fW4mHdtDTsmcXB3vIj5sOov/+ZnGBFJpiEdMMEPJF/QwVwZNyTj/TWQR2B
7/L9sy5YE/0MSCCJ8Wa+vL4o7WthkQoIKera3jrE3TBjPThSX3PNIKni9WpDaAgE
xvgs46HWUkmuZXAXOTA/iN5cegf6ZmCwfd8Q/p+IYdnfvy9Ici8ojs7pUq1AkCkj
XVwm0LsvyHt3/54AxqNriI4EnsTw9rn1yKHdWUoXk1BbTJsHYjZjTZ+WcXGhoSkB
yH+83fgm9GHRTVwZg0YGOFEqIAsv8oBBr09cxoTJzWET8t2Hlg0FoKzp0yd81hac
MCrG7WA9FDInZ0nhN8VQIhW0ZaNKFG1oV2swCa70GhF3cNNn8da21HBeU0DlsvbL
MuN7WcALDOQuH/Ooff+2wqLJ5IspQPSmlmbbGXruQD7NHjC31xuNoxo3CljIUxxs
R4sLjY5j8xqZjAyv3M3JmBpa15w+eV39ouHB4MytzVK7xcF0erRYdh6QdYL2uWom
S1mdPXvr82cNbM3kXHXlpxVSY+f5wcfIe+cQX2MIjRuvl2MoaMkMRPhCZ2Of193+
kgMvfPu2kkkGGtyfOgIouaw06KuJN0F0x+UaHi1BdKtbTB9SYf4=
=vu8H
-----END PGP SIGNATURE-----


E
E
Efraim Flashner wrote on 29 May 15:03 +0200
(address . 55608-done@debbugs.gnu.org)
YpNvLpWu/NDAix3b@3900XT
Patch pushed. Thanks for the review!

--
Efraim Flashner <efraim@flashner.co.il> אפרים פלשנר
GPG key = A28B F40C 3E55 1372 662D 14F7 41AA E7DC CA3D 8351
Confidentiality cannot be guaranteed on emails sent or received unencrypted
-----BEGIN PGP SIGNATURE-----

iQIzBAABCgAdFiEEoov0DD5VE3JmLRT3Qarn3Mo9g1EFAmKTby4ACgkQQarn3Mo9
g1Ed6RAAn2+nbETp/fvMWGGLcCj6HOz/JPMDWVwLHVPl52WVnqBYgcGFqgIT4Olm
GQxPZM+HNBGmndO12MMxq0hie6K2OgeV8kLxRpnjIUajalnLZucg2xl2fQSYSOZC
Fb683U7G0ocBX/E1aZxAjoug5tXtkkFasJ8hSoMNJKvfJJH0Lb1bcd7ewB+Vv7ei
UvX/TtiPs/qKIZlWegz7wQERX7/yE0UAu1YDHKGYCu8ubkh2eOoStpmnAGfM83FK
OzTaEji59NwGB2/4AAQWWu4U30waimH5i3zspaN+H66sn1bneHDAX+BmRdt7D3z4
UWMmhEZOcD7C4DELkPBIIgLCcYtpeOde8RAu/KJPYvt6C/aRWWzdKDCqYzXYsJz4
5IZMTAKroAv8S9zK6hKwMIHnu0y0Ox7EhprDEWeOYKyJ2ToHxoRt3z3Nq7vgCLPT
Gs6Q81VVPTb+3jZPDnW8zKVl1JzJ4JqYLz0ehKeWTJT5FuM/8Q86rfU1fKvMthqz
6M1thXDHcO8W/H5nvVzXE8FTcduPIuYk6ajuKu2+EKvmpeCMeOrgeqULI9Vu7U0+
OntDwqzQA9CvYPzz6gT12qBDz/V3F0JprO7l16yPhedCEl2l+jtf3SIsHVes1Wae
fAkbyDCH7jD+rKJx84yUdOUCbqizkZtkVgp9TGdWHsBocxt3U4w=
=0LC9
-----END PGP SIGNATURE-----


Closed
?
Your comment

This issue is archived.

To comment on this conversation send email to 55608@debbugs.gnu.org